File Nat.ML (Isabelle2005: October 2005)

# File Nat.ML

    (*  Title:      FOL/ex/Nat.ML
        ID:         $Id: Nat.ML,v 1.11 2005/09/03 15:15:51 wenzelm Exp $
        Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
        Copyright   1992  University of Cambridge

    Proofs about the natural numbers.

    To generate similar output to manual, execute these commands:
        Pretty.setmargin 72; print_depth 0;
    *)

    Goal "Suc(k) ~= k";
    by (res_inst_tac [("n","k")] induct 1);
    by (rtac notI 1);
    by (etac Suc_neq_0 1);
    by (rtac notI 1);
    by (etac notE 1);
    by (etac Suc_inject 1);
    qed "Suc_n_not_n";

    Goal "(k+m)+n = k+(m+n)";
    prths ([induct] RL [topthm()]);  (*prints all 14 next states!*)
    by (rtac induct 1);
    back();
    back();
    back();
    back();
    back();
    back();

    Goalw [add_def] "0+n = n";
    by (rtac rec_0 1);
    qed "add_0";

    Goalw [add_def] "Suc(m)+n = Suc(m+n)";
    by (rtac rec_Suc 1);
    qed "add_Suc";

    Addsimps [add_0, add_Suc];

    Goal "(k+m)+n = k+(m+n)";
    by (res_inst_tac [("n","k")] induct 1);
    by (Simp_tac 1);
    by (Asm_simp_tac 1);
    qed "add_assoc";

    Goal "m+0 = m";
    by (res_inst_tac [("n","m")] induct 1);
    by (Simp_tac 1);
    by (Asm_simp_tac 1);
    qed "add_0_right";

    Goal "m+Suc(n) = Suc(m+n)";
    by (res_inst_tac [("n","m")] induct 1);
    by (ALLGOALS (Asm_simp_tac));
    qed "add_Suc_right";

    (*Example used in Reference Manual, Doc/Ref/simplifier.tex*)
    val [prem] = Goal "(!!n. f(Suc(n)) = Suc(f(n))) ==> f(i+j) = i+f(j)";
    by (res_inst_tac [("n","i")] induct 1);
    by (Simp_tac 1);
    by (asm_simp_tac (simpset() addsimps [prem]) 1);
    result();