!
!     CalculiX - A 3-dimensional finite element program
!              Copyright (C) 1998-2005 Guido Dhondt
!
!     This program is free software; you can redistribute it and/or
!     modify it under the terms of the GNU General Public License as
!     published by the Free Software Foundation(version 2);
!     
!
!     This program is distributed in the hope that it will be useful,
!     but WITHOUT ANY WARRANTY; without even the implied warranty of 
!     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the 
!     GNU General Public License for more details.
!
!     You should have received a copy of the GNU General Public License
!     along with this program; if not, write to the Free Software
!     Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
!
      subroutine bodyforce(cbody,ibody,ipobody,nbody,set,istartset,
     &  iendset,ialset,inewton,nset)
!
!     assigns the body forces to the elements by use of field ipobody
!
      implicit none
!
      character*81 cbody(*),elset,set(*)
!
      integer ibody(2,*),nbody,ipobody(3,*),i,j,k,l,istartset(*),
     &  iendset(*),ialset(*),kindofbodyforce,inewton,nset,istat
!
      inewton=0
!
      do k=1,nbody
         elset=cbody(k)
         kindofbodyforce=ibody(1,k)
         inewton=max(inewton,kindofbodyforce)
!
!        check whether element number or set name
!
         read(elset,'(i21)',iostat=istat) l
         if(istat.eq.0) then
            ipobody(kindofbodyforce,l)=k
            cycle
         endif
!
         do i=1,nset
            if(set(i).eq.elset) exit
         enddo
!
         do j=istartset(i),iendset(i)
            if(ialset(j).gt.0) then
               ipobody(kindofbodyforce,ialset(j))=k
            else
               l=ialset(j-2)
               do
                  l=l-ialset(j)
                  if(l.ge.ialset(j-1)) exit
                  ipobody(kindofbodyforce,l)=k
               enddo
            endif
         enddo
      enddo
!
      if(inewton.eq.3) then
         inewton=1
      else
         inewton=0
      endif
!
      return
      end

