Introduction to Polynomials
===========================

Polynomials are stored in Maxima either in General Form or as Cannonical Rational Expressions (CRE) form.  The latter is a standard form, and is used internally by operations such as factor, ratsimp, and so on.

Canonical Rational Expressions constitute a kind of representation which is especially suitable for expanded polynomials and rational functions (as well as for partially factored polynomials and rational functions when RATFAC is set to true).  In this CRE form an ordering of variables (from most to least main) is assumed for each expression.  Polynomials are represented recursively by a list consisting of the main variable followed by a series of pairs of expressions, one for each term of the polynomial.  The first member of each pair is the exponent of the main variable in that term and the second member is the coefficient of that term which could be a number or a polynomial in another variable again represented in this form.  Thus the principal part of the CRE form of 3*X^2-1 is (X 2 3 0 -1) and that of 2*X*Y+X-3 is (Y 1 (X 1 2) 0 (X 1 1 0 -3)) assuming Y is the main variable, and is (X 1 (Y 1 2 0 1) 0 -3) assuming X is the main variable. "Main"-ness is usually determined by reverse alphabetical order.  The "variables" of a CRE expression needn't be atomic.  In fact any subexpression whose main operator is not + - * / or ^ with integer power will be considered a "variable" of the expression (in CRE form) in which it occurs.  For example the CRE variables of the expression X+SIN(X+1)+2*SQRT(X)+1 are X, SQRT(X), and SIN(X+1).  If the user does not specify an ordering of variables by using the RATVARS function Maxima will choose an alphabetic one.  In general, CRE's represent rational expressions, that is, ratios of polynomials, where the numerator and denominator have no common factors, and the denominator is positive.  The internal form is essentially a pair of polynomials (the numerator and denominator) preceded by the variable ordering list.  If an expression to be displayed is in CRE form or if it contains any subexpressions in CRE form, the symbol /R/ will follow the line label. See the RAT function for converting an expression to CRE form.  An extended CRE form is used for the representation of Taylor series.  The notion of a rational expression is extended so that the exponents of the variables can be positive or negative rational numbers rather than just positive integers and the coefficients can themselves be rational expressions as described above rather than just polynomials.  These are represented internally by a recursive polynomial form which is similar to and is a generalization of CRE form, but carries additional information such as the degree of truncation.  As with CRE form, the symbol /T/ follows the line label of such expressions.

Functions and Variables for Polynomials
=======================================

 -- Option variable: algebraic
     Default value: false

     algebraic must be set to true in order for the simplification of algebraic integers to take effect.

 -- Option variable: berlefact
     Default value: true

     When berlefact is false then the Kronecker factoring algorithm will be used otherwise the Berlekamp algorithm, which is the default, will be used.

 -- Function: bezout (P1, P2, X)
     an alternative to the resultant command.  It returns a matrix. determinant of this matrix is the desired resultant.

 -- Function: bothcoef (EXPR, X)
     Returns a list whose first member is the coefficient of X in EXPR (as found by ratcoef if EXPR is in CRE form otherwise by coeff) and whose second member is the remaining part of EXPR.  That is, [A, B] where EXPR = A*X + B.

     Example:

          (%i1) islinear (expr, x) := block ([c],
                  c: bothcoef (rat (expr, x), x),
                  is (freeof (x, c) and c[1] # 0))$
          (%i2) islinear ((r^2 - (x - r)^2)/x, x);
          (%o2)                         true

 -- Function: coeff (EXPR, X, N)
     Returns the coefficient of X^N in EXPR.  N may be omitted if it is 1.  X may be an atom, or complete subexpression of EXPR e.g., sin(x), a[i+1], x + y, etc. (In the last case the expression (x + y) should occur in EXPR).  Sometimes it may be necessary to expand or factor EXPR in order to make X^N explicit.  This is not done automatically by coeff.

     Examples:

          (%i1) coeff (2*a*tan(x) + tan(x) + b = 5*tan(x) + 3, tan(x));
          (%o1)                      2 a + 1 = 5
          (%i2) coeff (y + x*%e^x + 1, x, 0);
          (%o2)                         y + 1

 -- Function: combine (EXPR)
     Simplifies the sum EXPR by combining terms with the same denominator into a single term.

 -- Function: content (P_1, X_1, ..., X_N)
     Returns a list whose first element is the greatest common divisor of the coefficients of the terms of the polynomial P_1 in the variable X_N (this is the content) and whose second element is the polynomial P_1 divided by the content.

     Examples:

          (%i1) content (2*x*y + 4*x^2*y^2, y);
                                             2
          (%o1)                   [2 x, 2 x y  + y]

 -- Function: denom (EXPR)
     Returns the denominator of the rational expression EXPR.

 -- Function: divide (P_1, P_2, X_1, ..., X_N)
     computes the quotient and remainder of the polynomial P_1 divided by the polynomial P_2, in a main polynomial variable, X_N. The other variables are as in the ratvars function. The result is a list whose first element is the quotient and whose second element is the remainder.

     Examples:

          (%i1) divide (x + y, x - y, x);
          (%o1)                       [1, 2 y]
          (%i2) divide (x + y, x - y);
          (%o2)                      [- 1, 2 x]

     Note that y is the main variable in the second example.

 -- Function: eliminate ([EQN_1, ..., EQN_N], [X_1, ..., X_K])
     Eliminates variables from equations (or expressions assumed equal to zero) by taking successive resultants. This returns a list of N - K expressions with the K variables X_1, ..., X_K eliminated.  First X_1 is eliminated yielding N - 1 expressions, then x_2 is eliminated, etc.  If K = N then a single expression in a list is returned free of the variables X_1, ..., X_K.  In this case solve is called to solve the last resultant for the last variable.

     Example:

          (%i1) expr1: 2*x^2 + y*x + z;
                                                2
          (%o1)                    z + x y + 2 x
          (%i2) expr2: 3*x + 5*y - z - 1;
          (%o2)                  - z + 5 y + 3 x - 1
          (%i3) expr3: z^2 + x - y^2 + 5;
                                    2    2
          (%o3)                    z  - y  + x + 5
          (%i4) eliminate ([expr3, expr2, expr1], [y, z]);
                       8         7         6          5          4
          (%o4) [7425 x  - 1170 x  + 1299 x  + 12076 x  + 22887 x

                                              3         2
                                      - 5154 x  - 1291 x  + 7688 x + 15376]

 -- Function: ezgcd (P_1, P_2, P_3, ...)
     Returns a list whose first element is the g.c.d of the polynomials P_1, P_2, P_3, ...  and whose remaining elements are the polynomials divided by the g.c.d.  This always uses the ezgcd algorithm.

 -- Option variable: facexpand
     Default value: true

     facexpand controls whether the irreducible factors returned by factor are in expanded (the default) or recursive (normal CRE) form.

 -- Function: factcomb (EXPR)
     Tries to combine the coefficients of factorials in EXPR with the factorials themselves by converting, for example, (n + 1)*n! into (n + 1)!.

     sumsplitfact if set to false will cause minfactorial to be applied after a factcomb.

 -- Function: factor (EXPR)
     Factors the expression EXPR, containing any number of variables or functions, into factors irreducible over the integers. factor (EXPR, p) factors EXPR over the field of integers with an element adjoined whose minimum polynomial is p.

     factor uses ifactors function for factoring integers.

     factorflag if false suppresses the factoring of integer factors of rational expressions.

     dontfactor may be set to a list of variables with respect to which factoring is not to occur.  (It is initially empty).  Factoring also will not take place with respect to any variables which are less important (using the variable ordering assumed for CRE form) than those on the dontfactor list.

     savefactors if true causes the factors of an expression which is a product of factors to be saved by certain functions in order to speed up later factorizations of expressions containing some of the same factors.

     berlefact if false then the Kronecker factoring algorithm will be used otherwise the Berlekamp algorithm, which is the default, will be used.

     intfaclim if true maxima will give up factorization of integers if no factor is found after trial divisions and Pollard's rho method.  If set to false (this is the case when the user calls factor explicitly), complete factorization of the integer will be attempted.  The user's setting of intfaclim is used for internal calls to factor. Thus, intfaclim may be reset to prevent Maxima from taking an inordinately long time factoring large integers.

     Examples:

          (%i1) factor (2^63 - 1);
                              2
          (%o1)              7  73 127 337 92737 649657
          (%i2) factor (-8*y - 4*x + z^2*(2*y + x));
          (%o2)               (2 y + x) (z - 2) (z + 2)
          (%i3) -1 - 2*x - x^2 + y^2 + 2*x*y^2 + x^2*y^2;
                          2  2        2    2    2
          (%o3)          x  y  + 2 x y  + y  - x  - 2 x - 1
          (%i4) block ([dontfactor: [x]], factor (%/36/(1 + 2*y + y^2)));
                                 2
                               (x  + 2 x + 1) (y - 1)
          (%o4)                ----------------------
                                     36 (y + 1)
          (%i5) factor (1 + %e^(3*x));
                                x         2 x     x
          (%o5)              (%e  + 1) (%e    - %e  + 1)
          (%i6) factor (1 + x^4, a^2 - 2);
                              2              2
          (%o6)             (x  - a x + 1) (x  + a x + 1)
          (%i7) factor (-y^2*z^2 - x*z^2 + x^2*y^2 + x^3);
                                 2
          (%o7)              - (y  + x) (z - x) (z + x)
          (%i8) (2 + x)/(3 + x)/(b + x)/(c + x)^2;
                                       x + 2
          (%o8)               ------------------------
                                                     2
                              (x + 3) (x + b) (x + c)
          (%i9) ratsimp (%);
                          4                  3
          (%o9) (x + 2)/(x  + (2 c + b + 3) x

               2                       2             2                   2
           + (c  + (2 b + 6) c + 3 b) x  + ((b + 3) c  + 6 b c) x + 3 b c )
          (%i10) partfrac (%, x);
                     2                   4                3
          (%o10) - (c  - 4 c - b + 6)/((c  + (- 2 b - 6) c

               2              2         2                2
           + (b  + 12 b + 9) c  + (- 6 b  - 18 b) c + 9 b ) (x + c))

                           c - 2
           - ---------------------------------
               2                             2
             (c  + (- b - 3) c + 3 b) (x + c)

                                   b - 2
           + -------------------------------------------------
                       2             2       3      2
             ((b - 3) c  + (6 b - 2 b ) c + b  - 3 b ) (x + b)

                                   1
           - ----------------------------------------------
                       2
             ((b - 3) c  + (18 - 6 b) c + 9 b - 27) (x + 3)
          (%i11) map ('factor, %);
                        2
                       c  - 4 c - b + 6                 c - 2
          (%o11) - ------------------------- - ------------------------
                          2        2                                  2
                   (c - 3)  (c - b)  (x + c)   (c - 3) (c - b) (x + c)

                                 b - 2                        1
                      + ------------------------ - ------------------------
                                       2                          2
                        (b - 3) (c - b)  (x + b)   (b - 3) (c - 3)  (x + 3)
          (%i12) ratsimp ((x^5 - 1)/(x - 1));
                                 4    3    2
          (%o12)                x  + x  + x  + x + 1
          (%i13) subst (a, x, %);
                                 4    3    2
          (%o13)                a  + a  + a  + a + 1
          (%i14) factor (%th(2), %);
                                 2        3        3    2
          (%o14)   (x - a) (x - a ) (x - a ) (x + a  + a  + a + 1)
          (%i15) factor (1 + x^12);
                                 4        8    4
          (%o15)               (x  + 1) (x  - x  + 1)
          (%i16) factor (1 + x^99);
                           2            6    3
          (%o16) (x + 1) (x  - x + 1) (x  - x  + 1)

             10    9    8    7    6    5    4    3    2
           (x   - x  + x  - x  + x  - x  + x  - x  + x  - x + 1)

             20    19    17    16    14    13    11    10    9    7    6
           (x   + x   - x   - x   + x   + x   - x   - x   - x  + x  + x

              4    3            60    57    51    48    42    39    33
           - x  - x  + x + 1) (x   + x   - x   - x   + x   + x   - x

              30    27    21    18    12    9    3
           - x   - x   + x   + x   - x   - x  + x  + 1)

 -- Option variable: factorflag
     Default value: false

     When factorflag is false, suppresses the factoring of integer factors of rational expressions.

 -- Function: factorout (EXPR, X_1, X_2, ...)
     Rearranges the sum EXPR into a sum of terms of the form f (X_1, X_2, ...)*g where g is a product of expressions not containing any X_I and f is factored.

 -- Function: factorsum (EXPR)
     Tries to group terms in factors of EXPR which are sums into groups of terms such that their sum is factorable.  factorsum can recover the result of expand ((x + y)^2 + (z + w)^2) but it can't recover expand ((x + 1)^2 + (x + y)^2) because the terms have variables in common.

     Example:

          (%i1) expand ((x + 1)*((u + v)^2 + a*(w + z)^2));
                     2      2                            2      2
          (%o1) a x z  + a z  + 2 a w x z + 2 a w z + a w  x + v  x

                                               2        2    2            2
                                  + 2 u v x + u  x + a w  + v  + 2 u v + u
          (%i2) factorsum (%);
                                             2          2
          (%o2)            (x + 1) (a (z + w)  + (v + u) )

 -- Function: fasttimes (P_1, P_2)
     Returns the product of the polynomials P_1 and P_2 by using a special algorithm for multiplication of polynomials.  p_1 and p_2 should be multivariate, dense, and nearly the same size.  Classical multiplication is of order n_1 n_2 where n_1 is the degree of p_1 and n_2 is the degree of p_2. fasttimes is of order max (n_1, n_2)^1.585.

 -- Function: fullratsimp (EXPR)
     fullratsimp repeatedly applies ratsimp followed by non-rational simplification to an expression until no further change occurs, and returns the result.

     When non-rational expressions are involved, one call to ratsimp followed as is usual by non-rational ("general") simplification may not be sufficient to return a simplified result. Sometimes, more than one such call may be necessary. fullratsimp makes this process convenient.

     fullratsimp (EXPR, X_1, ..., X_N) takes one or more arguments similar to ratsimp and rat.

     Example:

          (%i1) expr: (x^(a/2) + 1)^2*(x^(a/2) - 1)^2/(x^a - 1);
                                 a/2     2   a/2     2
                               (x    - 1)  (x    + 1)
          (%o1)                -----------------------
                                        a
                                       x  - 1
          (%i2) ratsimp (expr);
                                    2 a      a
                                   x    - 2 x  + 1
          (%o2)                    ---------------
                                        a
                                       x  - 1
          (%i3) fullratsimp (expr);
                                        a
          (%o3)                        x  - 1
          (%i4) rat (expr);
                                 a/2 4       a/2 2
                               (x   )  - 2 (x   )  + 1
          (%o4)/R/             -----------------------
                                        a
                                       x  - 1

 -- Function: fullratsubst (A, B, C)
     is the same as ratsubst except that it calls itself recursively on its result until that result stops changing. This function is useful when the replacement expression and the replaced expression have one or more variables in common.

     fullratsubst will also accept its arguments in the format of lratsubst.  That is, the first argument may be a single substitution equation or a list of such equations, while the second argument is the expression being processed.

     load ("lrats") loads fullratsubst and lratsubst.

     Examples:

          (%i1) load ("lrats")$

       * subst can carry out multiple substitutions. lratsubst is analogous to subst.

          (%i2) subst ([a = b, c = d], a + c);
          (%o2)                         d + b
          (%i3) lratsubst ([a^2 = b, c^2 = d], (a + e)*c*(a + c));
          (%o3)                (d + a c) e + a d + b c

       * If only one substitution is desired, then a single equation may be given as first argument.

          (%i4) lratsubst (a^2 = b, a^3);
          (%o4)                          a b

       * fullratsubst is equivalent to ratsubst except that it recurses until its result stops changing.

          (%i5) ratsubst (b*a, a^2, a^3);
                                         2
          (%o5)                         a  b
          (%i6) fullratsubst (b*a, a^2, a^3);
                                           2
          (%o6)                         a b

       * fullratsubst also accepts a list of equations or a single equation as first argument.

          (%i7) fullratsubst ([a^2 = b, b^2 = c, c^2 = a], a^3*b*c);
          (%o7)                           b
          (%i8) fullratsubst (a^2 = b*a, a^3);
                                           2
          (%o8)                         a b

       * fullratsubst may cause an indefinite recursion.

          (%i9) errcatch (fullratsubst (b*a^2, a^2, a^3));

          *** - Lisp stack overflow. RESET

 -- Function: gcd (P_1, P_2, X_1, ...)
     Returns the greatest common divisor of P_1 and P_2. The flag gcd determines which algorithm is employed. Setting gcd to ez, subres, red, or spmod selects the ezgcd, subresultant prs, reduced, or modular algorithm, respectively.  If gcd false then gcd (P_1, P_2, X) always returns 1 for all X.  Many functions (e.g.  ratsimp, factor, etc.) cause gcd's to be taken implicitly.  For homogeneous polynomials it is recommended that gcd equal to subres be used.  To take the gcd when an algebraic is present, e.g., gcd (X^2 - 2*sqrt(2)*X + 2, X - sqrt(2)), algebraic must be true and gcd must not be ez.  subres is a new algorithm, and people who have been using the red setting should probably change it to subres.

     The gcd flag, default: subres, if false will also prevent the greatest common divisor from being taken when expressions are converted to canonical rational expression (CRE) form.  This will sometimes speed the calculation if gcds are not required.

 -- Function: gcdex (F, G)
 -- Function: gcdex (F, G, X)
     Returns a list [A, B, U] where U is the greatest common divisor (gcd) of F and G, and U is equal to A F + B G. The arguments F and G should be univariate polynomials, or else polynomials in X a supplied main variable since we need to be in a principal ideal domain for this to work. The gcd means the gcd regarding F and G as univariate polynomials with coefficients being rational functions in the other variables.

     gcdex implements the Euclidean algorithm, where we have a sequence of L[i]: [a[i], b[i], r[i]] which are all perpendicular to [f, g, -1] and the next one is built as if q = quotient(r[i]/r[i+1]) then L[i+2]: L[i] - q L[i+1], and it terminates at L[i+1] when the remainder r[i+2] is zero.

          (%i1) gcdex (x^2 + 1, x^3 + 4);
                                 2
                                x  + 4 x - 1  x + 4
          (%o1)/R/           [- ------------, -----, 1]
                                     17        17
          (%i2) % . [x^2 + 1, x^3 + 4, -1];
          (%o2)/R/                        0

     Note that the gcd in the following is 1 since we work in k(y)[x], not the  y+1 we would expect in k[y, x].

          (%i1) gcdex (x*(y + 1), y^2 - 1, x);
                                         1
          (%o1)/R/                 [0, ------, 1]
                                        2
                                       y  - 1

 -- Function: gcfactor (N)
     Factors the Gaussian integer N over the Gaussian integers, i.e., numbers of the form A + B %i where A and B are rational integers (i.e.,  ordinary integers).  Factors are normalized by making A and B non-negative.

 -- Function: gfactor (EXPR)
     Factors the polynomial EXPR over the Gaussian integers (that is, the integers with the imaginary unit %i adjoined). This is like factor (EXPR, A^2+1) where A is %i.

     Example:

          (%i1) gfactor (x^4 - 1);
          (%o1)           (x - 1) (x + 1) (x - %i) (x + %i)

 -- Function: gfactorsum (EXPR)
     is similar to factorsum but applies gfactor instead of factor.

 -- Function: hipow (EXPR, X)
     Returns the highest explicit exponent of X in EXPR. X may be a variable or a general expression. If X does not appear in EXPR, hipow returns 0.

     hipow does not consider expressions equivalent to expr. In particular, hipow does not expand expr, so hipow (EXPR, X) and hipow (expand (EXPR, X)) may yield different results.

     Examples:

          (%i1) hipow (y^3 * x^2 + x * y^4, x);
          (%o1)                           2
          (%i2) hipow ((x + y)^5, x);
          (%o2)                           1
          (%i3) hipow (expand ((x + y)^5), x);
          (%o3)                           5
          (%i4) hipow ((x + y)^5, x + y);
          (%o4)                           5
          (%i5) hipow (expand ((x + y)^5), x + y);
          (%o5)                           0

 -- Option variable: intfaclim
     Default value: true

     If true, maxima will give up factorization of integers if no factor is found after trial divisions and Pollard's rho method and factorization will not be complete.

     When intfaclim is false (this is the case when the user calls factor explicitly), complete factorization will be attempted.  intfaclim is set to false when factors are computed in divisors, divsum and totient.

     Internal calls to factor respect the user-specified value of intfaclim.  Setting intfaclim to true may reduce the time spent factoring large integers.

 -- Option variable: keepfloat
     Default value: false

     When keepfloat is true, prevents floating point numbers from being rationalized when expressions which contain them are converted to canonical rational expression (CRE) form.

 -- Function: lratsubst (L, EXPR)
     is analogous to subst (L, EXPR) except that it uses ratsubst instead of subst.

     The first argument of lratsubst is an equation or a list of equations identical in format to that accepted by subst.  The substitutions are made in the order given by the list of equations, that is, from left to right.

     load ("lrats") loads fullratsubst and lratsubst.

     Examples:

          (%i1) load ("lrats")$

       * subst can carry out multiple substitutions. lratsubst is analogous to subst.

          (%i2) subst ([a = b, c = d], a + c);
          (%o2)                         d + b
          (%i3) lratsubst ([a^2 = b, c^2 = d], (a + e)*c*(a + c));
          (%o3)                (d + a c) e + a d + b c

       * If only one substitution is desired, then a single equation may be given as first argument.

          (%i4) lratsubst (a^2 = b, a^3);
          (%o4)                          a b

 -- Option variable: modulus
     Default value: false

     When modulus is a positive number P, operations on rational numbers (as returned by rat and related functions) are carried out modulo P, using the so-called "balanced" modulus system in which N modulo P is defined as an integer K in [-(P-1)/2, ..., 0, ..., (P-1)/2] when P is odd, or [-(P/2 - 1), ..., 0, ...., P/2] when P is even, such that A P + K equals N for some integer A.

     If EXPR is already in canonical rational expression (CRE) form when modulus is reset, then you may need to re-rat EXPR, e.g., expr: rat (ratdisrep (expr)), in order to get correct results.

     Typically modulus is set to a prime number. If modulus is set to a positive non-prime integer, this setting is accepted, but a warning message is displayed. Maxima will allow zero or a negative integer to be assigned to modulus, although it is not clear if that has any useful consequences.

 -- Function: num (EXPR)
     Returns the numerator of EXPR if it is a ratio. If EXPR is not a ratio, EXPR is returned.

     num evaluates its argument.

 -- Function: polydecomp (P, X)

     Decomposes the polynomial P in the variable X into the functional composition of polynomials in X. polydecomp returns a list [P_1, ..., P_N] such that

          lambda ([x], p_1) (lambda ([x], p_2) (... (lambda ([x], p_n) (x))
            ...))

     is equal to P. The degree of P_I is greater than 1 for I less than N.

     Such a decomposition is not unique.

     Examples:

          (%i1) polydecomp (x^210, x);
                                    7   5   3   2
          (%o1)                   [x , x , x , x ]
          (%i2) p : expand (subst (x^3 - x - 1, x, x^2 - a));
                          6      4      3    2
          (%o2)          x  - 2 x  - 2 x  + x  + 2 x - a + 1
          (%i3) polydecomp (p, x);
                                  2       3
          (%o3)                 [x  - a, x  - x - 1]

     The following function composes L = [e_1, ..., e_n] as functions in x; it is the inverse of polydecomp:

          compose (L, x) :=
            block ([r : x], for e in L do r : subst (e, x, r), r) $

     Re-express above example using compose:

          (%i3) polydecomp (compose ([x^2 - a, x^3 - x - 1], x), x);
                                  2       3
          (%o3)                 [x  - a, x  - x - 1]

     Note that though compose (polydecomp (P, X), X) always returns P (unexpanded), polydecomp (compose ([P_1, ..., P_N], X), X) does not necessarily return [P_1, ..., P_N]:

          (%i4) polydecomp (compose ([x^2 + 2*x + 3, x^2], x), x);
                                    2       2
          (%o4)                   [x  + 2, x  + 1]
          (%i5) polydecomp (compose ([x^2 + x + 1, x^2 + x + 1], x), x);
                                2       2
                               x  + 3  x  + 5
          (%o5)               [------, ------, 2 x + 1]
                                 4       2

 -- Function: quotient (P_1, P_2)
 -- Function: quotient (P_1, P_2, X_1, ..., X_N)
     Returns the polynomial P_1 divided by the polynomial P_2. The arguments X_1, ..., X_N are interpreted as in ratvars.

     quotient returns the first element of the two-element list returned by divide.

 -- Function: rat (EXPR)
 -- Function: rat (EXPR, X_1, ..., X_N)
     Converts EXPR to canonical rational expression (CRE) form by expanding and combining all terms over a common denominator and cancelling out the greatest common divisor of the numerator and denominator, as well as converting floating point numbers to rational numbers within a tolerance of ratepsilon. The variables are ordered according to the X_1, ..., X_N, if specified, as in ratvars.

     rat does not generally simplify functions other than addition +, subtraction -, multiplication *, division /, and exponentiation to an integer power, whereas ratsimp does handle those cases. Note that atoms (numbers and variables) in CRE form are not the same as they are in the general form. For example, rat(x)- x yields rat(0) which has a different internal representation than 0.

     When ratfac is true, rat yields a partially factored form for CRE. During rational operations the expression is maintained as fully factored as possible without an actual call to the factor package.  This should always save space and may save some time in some computations.  The numerator and denominator are still made relatively prime (e.g.  rat ((x^2 - 1)^4/(x + 1)^2) yields (x - 1)^4 (x + 1)^2), but the factors within each part may not be relatively prime.

     ratprint if false suppresses the printout of the message informing the user of the conversion of floating point numbers to rational numbers.

     keepfloat if true prevents floating point numbers from being converted to rational numbers.

     See also ratexpand and  ratsimp.

     Examples:

          (%i1) ((x - 2*y)^4/(x^2 - 4*y^2)^2 + 1)*(y + a)*(2*y + x) /
                (4*y^2 + x^2);
                                                     4
                                            (x - 2 y)
                        (y + a) (2 y + x) (------------ + 1)
                                             2      2 2
                                           (x  - 4 y )
          (%o1)         ------------------------------------
                                        2    2
                                     4 y  + x
          (%i2) rat (%, y, a, x);
                                      2 a + 2 y
          (%o2)/R/                    ---------
                                       x + 2 y

 -- Option variable: ratalgdenom
     Default value: true

     When ratalgdenom is true, allows rationalization of denominators with respect to radicals to take effect. ratalgdenom has an effect only when canonical rational expressions (CRE) are used in algebraic mode.

 -- Function: ratcoef (EXPR, X, N)
 -- Function: ratcoef (EXPR, X)
     Returns the coefficient of the expression X^N in the expression EXPR. If omitted, N is assumed to be 1.

     The return value is free (except possibly in a non-rational sense) of the variables in X. If no coefficient of this type exists, 0 is returned.

     ratcoef expands and rationally simplifies its first argument and thus it may produce answers different from those of coeff which is purely syntactic. Thus ratcoef ((x + 1)/y + x, x) returns (y + 1)/y whereas coeff returns 1.

     ratcoef (EXPR, X, 0), viewing EXPR as a sum, returns a sum of those terms which do not contain X. Therefore if X occurs to any negative powers, ratcoef should not be used.

     Since EXPR is rationally simplified before it is examined, coefficients may not appear quite the way they were envisioned.

     Example:

          (%i1) s: a*x + b*x + 5$
          (%i2) ratcoef (s, a + b);
          (%o2)                           x

 -- Function: ratdenom (EXPR)
     Returns the denominator of EXPR, after coercing EXPR to a canonical rational expression (CRE). The return value is a CRE.

     EXPR is coerced to a CRE by rat if it is not already a CRE. This conversion may change the form of EXPR by putting all terms over a common denominator.

     denom is similar, but returns an ordinary expression instead of a CRE. Also, denom does not attempt to place all terms over a common denominator, and thus some expressions which are considered ratios by ratdenom are not considered ratios by denom.

 -- Option variable: ratdenomdivide
     Default value: true

     When ratdenomdivide is true, ratexpand expands a ratio in which the numerator is a sum into a sum of ratios, all having a common denominator. Otherwise, ratexpand collapses a sum of ratios into a single ratio, the numerator of which is the sum of the numerators of each ratio.

     Examples:

          (%i1) expr: (x^2 + x + 1)/(y^2 + 7);
                                      2
                                     x  + x + 1
          (%o1)                      ----------
                                        2
                                       y  + 7
          (%i2) ratdenomdivide: true$
          (%i3) ratexpand (expr);
                                 2
                                x        x        1
          (%o3)               ------ + ------ + ------
                               2        2        2
                              y  + 7   y  + 7   y  + 7
          (%i4) ratdenomdivide: false$
          (%i5) ratexpand (expr);
                                      2
                                     x  + x + 1
          (%o5)                      ----------
                                        2
                                       y  + 7
          (%i6) expr2: a^2/(b^2 + 3) + b/(b^2 + 3);
                                               2
                                     b        a
          (%o6)                    ------ + ------
                                    2        2
                                   b  + 3   b  + 3
          (%i7) ratexpand (expr2);
                                            2
                                       b + a
          (%o7)                        ------
                                        2
                                       b  + 3

 -- Function: ratdiff (EXPR, X)
     Differentiates the rational expression EXPR with respect to X. EXPR must be a ratio of polynomials or a polynomial in X. The argument X may be a variable or a subexpression of EXPR.

     The result is equivalent to diff, although perhaps in a different form. ratdiff may be faster than diff, for rational expressions.

     ratdiff returns a canonical rational expression (CRE) if expr is a CRE. Otherwise, ratdiff returns a general expression.

     ratdiff considers only the dependence of EXPR on X, and ignores any dependencies established by depends.

     Example:

          (%i1) expr: (4*x^3 + 10*x - 11)/(x^5 + 5);
                                     3
                                  4 x  + 10 x - 11
          (%o1)                   ----------------
                                        5
                                       x  + 5
          (%i2) ratdiff (expr, x);
                              7       5       4       2
                           8 x  + 40 x  - 55 x  - 60 x  - 50
          (%o2)          - ---------------------------------
                                    10       5
                                   x   + 10 x  + 25
          (%i3) expr: f(x)^3 - f(x)^2 + 7;
                                   3       2
          (%o3)                   f (x) - f (x) + 7
          (%i4) ratdiff (expr, f(x));
                                     2
          (%o4)                   3 f (x) - 2 f(x)
          (%i5) expr: (a + b)^3 + (a + b)^2;
                                        3          2
          (%o5)                  (b + a)  + (b + a)
          (%i6) ratdiff (expr, a + b);
                              2                    2
          (%o6)            3 b  + (6 a + 2) b + 3 a  + 2 a

 -- Function: ratdisrep (EXPR)
     Returns its argument as a general expression. If EXPR is a general expression, it is returned unchanged.

     Typically ratdisrep is called to convert a canonical rational expression (CRE) into a general expression. This is sometimes convenient if one wishes to stop the "contagion", or use rational functions in non-rational contexts.

     See also totaldisrep.

 -- Option variable: ratepsilon
     Default value: 2.0e-8

     ratepsilon is the tolerance used in the conversion of floating point numbers to rational numbers.

 -- Function: ratexpand (EXPR)
 -- Option variable: ratexpand
     Expands EXPR by multiplying out products of sums and exponentiated sums, combining fractions over a common denominator, cancelling the greatest common divisor of the numerator and denominator, then splitting the numerator (if a sum) into its respective terms divided by the denominator.

     The return value of ratexpand is a general expression, even if EXPR is a canonical rational expression (CRE).

     The switch ratexpand if true will cause CRE expressions to be fully expanded when they are converted back to general form or displayed, while if it is false then they will be put into a recursive form. See also ratsimp.

     When ratdenomdivide is true, ratexpand expands a ratio in which the numerator is a sum into a sum of ratios, all having a common denominator. Otherwise, ratexpand collapses a sum of ratios into a single ratio, the numerator of which is the sum of the numerators of each ratio.

     When keepfloat is true, prevents floating point numbers from being rationalized when expressions which contain them are converted to canonical rational expression (CRE) form.

     Examples:

          (%i1) ratexpand ((2*x - 3*y)^3);
                               3         2       2        3
          (%o1)          - 27 y  + 54 x y  - 36 x  y + 8 x
          (%i2) expr: (x - 1)/(x + 1)^2 + 1/(x - 1);
                                   x - 1       1
          (%o2)                   -------- + -----
                                         2   x - 1
                                  (x + 1)
          (%i3) expand (expr);
                              x              1           1
          (%o3)          ------------ - ------------ + -----
                          2              2             x - 1
                         x  + 2 x + 1   x  + 2 x + 1
          (%i4) ratexpand (expr);
                                  2
                               2 x                 2
          (%o4)           --------------- + ---------------
                           3    2            3    2
                          x  + x  - x - 1   x  + x  - x - 1

 -- Option variable: ratfac
     Default value: false

     When ratfac is true, canonical rational expressions (CRE) are manipulated in a partially factored form.

     During rational operations the expression is maintained as fully factored as possible without calling factor. This should always save space and may save time in some computations. The numerator and denominator are made relatively prime, for example rat ((x^2 - 1)^4/(x + 1)^2) yields (x - 1)^4 (x + 1)^2), but the factors within each part may not be relatively prime.

     In the ctensr (Component Tensor Manipulation) package, Ricci, Einstein, Riemann, and Weyl tensors and the scalar curvature are factored automatically when ratfac is true. ratfac should only be set for cases where the tensorial components are known to consist of few terms.

     The ratfac and ratweight schemes are incompatible and may not both be used at the same time.

 -- Function: ratnumer (EXPR)
     Returns the numerator of EXPR, after coercing EXPR to a canonical rational expression (CRE). The return value is a CRE.

     EXPR is coerced to a CRE by rat if it is not already a CRE. This conversion may change the form of EXPR by putting all terms over a common denominator.

     num is similar, but returns an ordinary expression instead of a CRE. Also, num does not attempt to place all terms over a common denominator, and thus some expressions which are considered ratios by ratnumer are not considered ratios by num.

 -- Function: ratnump (EXPR)
     Returns true if EXPR is a literal integer or ratio of literal integers, otherwise false.

 -- Function: ratp (EXPR)
     Returns true if EXPR is a canonical rational expression (CRE) or extended CRE, otherwise false.

     CRE are created by rat and related functions. Extended CRE are created by taylor and related functions.

 -- Option variable: ratprint
     Default value: true

     When ratprint is true, a message informing the user of the conversion of floating point numbers to rational numbers is displayed.

 -- Function: ratsimp (EXPR)
 -- Function: ratsimp (EXPR, X_1, ..., X_N)
     Simplifies the expression EXPR and all of its subexpressions, including the arguments to non-rational functions. The result is returned as the quotient of two polynomials in a recursive form, that is, the coefficients of the main variable are polynomials in the other variables. Variables may include non-rational functions (e.g., sin (x^2 + 1)) and the arguments to any such functions are also rationally simplified.

     ratsimp (EXPR, X_1, ..., X_N) enables rational simplification with the specification of variable ordering as in ratvars.

     When ratsimpexpons is true, ratsimp is applied to the exponents of expressions during simplification.

     See also ratexpand. Note that ratsimp is affected by some of the flags which affect ratexpand.

     Examples:

          (%i1) sin (x/(x^2 + x)) = exp ((log(x) + 1)^2 - log(x)^2);
                                                   2      2
                             x         (log(x) + 1)  - log (x)
          (%o1)        sin(------) = %e
                            2
                           x  + x
          (%i2) ratsimp (%);
                                       1          2
          (%o2)                  sin(-----) = %e x
                                     x + 1
          (%i3) ((x - 1)^(3/2) - (x + 1)*sqrt(x - 1))/sqrt((x - 1)*(x + 1));
                                 3/2
                          (x - 1)    - sqrt(x - 1) (x + 1)
          (%o3)           --------------------------------
                               sqrt((x - 1) (x + 1))
          (%i4) ratsimp (%);
                                     2 sqrt(x - 1)
          (%o4)                    - -------------
                                           2
                                     sqrt(x  - 1)
          (%i5) x^(a + 1/a), ratsimpexpons: true;
                                         2
                                        a  + 1
                                        ------
                                          a
          (%o5)                        x

 -- Option variable: ratsimpexpons
     Default value: false

     When ratsimpexpons is true, ratsimp is applied to the exponents of expressions during simplification.

 -- Function: ratsubst (A, B, C)
     Substitutes A for B in C and returns the resulting expression. B may be a sum, product, power, etc.

     ratsubst knows something of the meaning of expressions whereas subst does a purely syntactic substitution. Thus subst (a, x + y, x + y + z) returns x + y + z whereas ratsubst returns z + a.

     When radsubstflag is true, ratsubst makes substitutions for radicals in expressions which don't explicitly contain them.

     Examples:

          (%i1) ratsubst (a, x*y^2, x^4*y^3 + x^4*y^8);
                                        3      4
          (%o1)                      a x  y + a
          (%i2) cos(x)^4 + cos(x)^3 + cos(x)^2 + cos(x) + 1;
                         4         3         2
          (%o2)       cos (x) + cos (x) + cos (x) + cos(x) + 1
          (%i3) ratsubst (1 - sin(x)^2, cos(x)^2, %);
                      4           2                     2
          (%o3)    sin (x) - 3 sin (x) + cos(x) (2 - sin (x)) + 3
          (%i4) ratsubst (1 - cos(x)^2, sin(x)^2, sin(x)^4);
                                  4           2
          (%o4)                cos (x) - 2 cos (x) + 1
          (%i5) radsubstflag: false$
          (%i6) ratsubst (u, sqrt(x), x);
          (%o6)                           x
          (%i7) radsubstflag: true$
          (%i8) ratsubst (u, sqrt(x), x);
                                          2
          (%o8)                          u

 -- Function: ratvars (X_1, ..., X_N)
 -- Function: ratvars ()
 -- System variable: ratvars
     Declares main variables X_1, ..., X_N for rational expressions. X_N, if present in a rational expression, is considered the main variable. Otherwise, X_[N-1] is considered the main variable if present, and so on through the preceding variables to X_1, which is considered the main variable only if none of the succeeding variables are present.

     If a variable in a rational expression is not present in the ratvars list, it is given a lower priority than X_1.

     The arguments to ratvars can be either variables or non-rational functions such as sin(x).

     The variable ratvars is a list of the arguments of the function ratvars when it was called most recently. Each call to the function ratvars resets the list. ratvars () clears the list.

 -- Function: ratweight (X_1, W_1, ..., X_N, W_N)
 -- Function: ratweight ()
     Assigns a weight W_I to the variable X_I. This causes a term to be replaced by 0 if its weight exceeds the value of the variable ratwtlvl (default yields no truncation). The weight of a term is the sum of the products of the weight of a variable in the term times its power. For example, the weight of 3 x_1^2 x_2 is 2 w_1 + w_2. Truncation according to ratwtlvl is carried out only when multiplying or exponentiating canonical rational expressions (CRE).

     ratweight () returns the cumulative list of weight assignments.

     Note: The ratfac and ratweight schemes are incompatible and may not both be used at the same time.

     Examples:

          (%i1) ratweight (a, 1, b, 1);
          (%o1)                     [a, 1, b, 1]
          (%i2) expr1: rat(a + b + 1)$
          (%i3) expr1^2;
                            2                  2
          (%o3)/R/         b  + (2 a + 2) b + a  + 2 a + 1
          (%i4) ratwtlvl: 1$
          (%i5) expr1^2;
          (%o5)/R/                  2 b + 2 a + 1

 -- System variable: ratweights
     Default value: []

     ratweights is the list of weights assigned by ratweight. The list is cumulative: each call to ratweight places additional items in the list.

     kill (ratweights) and save (ratweights) both work as expected.

 -- Option variable: ratwtlvl
     Default value: false

     ratwtlvl is used in combination with the ratweight function to control the truncation of canonical rational expressions (CRE). For the default value of false, no truncation occurs.

 -- Function: remainder (P_1, P_2)
 -- Function: remainder (P_1, P_2, X_1, ..., X_N)
     Returns the remainder of the polynomial P_1 divided by the polynomial P_2. The arguments X_1, ..., X_N are interpreted as in ratvars.

     remainder returns the second element of the two-element list returned by divide.

 -- Function: resultant (P_1, P_2, X)
 -- Variable: resultant
     Computes the resultant of the two polynomials P_1 and P_2, eliminating the variable X. The resultant is a determinant of the coefficients of X in P_1 and P_2, which equals zero if and only if P_1 and P_2 have a non-constant factor in common.

     If P_1 or P_2 can be factored, it may be desirable to call factor before calling resultant.

     The variable resultant controls which algorithm will be used to compute the resultant. subres for subresultant prs, mod for modular resultant algorithm, and red for reduced prs. On most problems subres should be best. On some large degree univariate or bivariate problems mod may be better.

     The function bezout takes the same arguments as resultant and returns a matrix.  The determinant of the return value is the desired resultant.

 -- Option variable: savefactors
     Default value: false

     When savefactors is true, causes the factors of an expression which is a product of factors to be saved by certain functions in order to speed up later factorizations of expressions containing some of the same factors.

 -- Function: sqfr (EXPR)
     is similar to factor except that the polynomial factors are "square-free." That is, they have factors only of degree one. This algorithm, which is also used by the first stage of factor, utilizes the fact that a polynomial has in common with its n'th derivative all its factors of degree greater than n.  Thus by taking greatest common divisors with the polynomial of the derivatives with respect to each variable in the polynomial, all factors of degree greater than 1 can be found.

     Example:

          (%i1) sqfr (4*x^4 + 4*x^3 - 3*x^2 - 4*x - 1);
                                          2   2
          (%o1)                  (2 x + 1)  (x  - 1)

 -- Function: tellrat (P_1, ..., P_N)
 -- Function: tellrat ()
     Adds to the ring of algebraic integers known to Maxima the elements which are the solutions of the polynomials P_1, ..., P_N. Each argument P_I is a polynomial with integer coefficients.

     tellrat (X) effectively means substitute 0 for X in rational functions.

     tellrat () returns a list of the current substitutions.

     algebraic must be set to true in order for the simplification of algebraic integers to take effect.

     Maxima initially knows about the imaginary unit %i and all roots of integers.

     There is a command untellrat which takes kernels and removes tellrat properties.

     When tellrat'ing a multivariate polynomial, e.g., tellrat (x^2 - y^2), there would be an ambiguity as to whether to substitute Y^2 for X^2 or vice versa. Maxima picks a particular ordering, but if the user wants to specify which, e.g. tellrat (y^2 = x^2) provides a syntax which says replace Y^2 by X^2.

     Examples:

          (%i1) 10*(%i + 1)/(%i + 3^(1/3));
                                     10 (%i + 1)
          (%o1)                      -----------
                                            1/3
                                      %i + 3
          (%i2) ev (ratdisrep (rat(%)), algebraic);
                       2/3      1/3              2/3      1/3
          (%o2)    (4 3    - 2 3    - 4) %i + 2 3    + 4 3    - 2
          (%i3) tellrat (1 + a + a^2);
                                      2
          (%o3)                     [a  + a + 1]
          (%i4) 1/(a*sqrt(2) - 1) + a/(sqrt(3) + sqrt(2));
                                1                 a
          (%o4)           ------------- + -----------------
                          sqrt(2) a - 1   sqrt(3) + sqrt(2)
          (%i5) ev (ratdisrep (rat(%)), algebraic);
                   (7 sqrt(3) - 10 sqrt(2) + 2) a - 2 sqrt(2) - 1
          (%o5)    ----------------------------------------------
                                         7
          (%i6) tellrat (y^2 = x^2);
                                  2    2   2
          (%o6)                 [y  - x , a  + a + 1]

 -- Function: totaldisrep (EXPR)
     Converts every subexpression of EXPR from canonical rational expressions (CRE) to general form and returns the result. If EXPR is itself in CRE form then totaldisrep is identical to ratdisrep.

     totaldisrep may be useful for ratdisrepping expressions such as equations, lists, matrices, etc., which have some subexpressions in CRE form.

 -- Function: untellrat (X_1, ..., X_N)
     Removes tellrat properties from X_1, ..., X_N.