Introducedilhaão a manipulacedilhaão de sequências de caracteres
================================================================

O ficheiro stringproc.lisp amplia a compatibilidade do Maxima de trabalhar com sequências de caracteres e adiciona algumas funções úteis a entrada e saída de dados.

Para esclarecimentos e erros por favor mande um e-mail para van.nek at arcor.de .

Para disponibilizar stringproc.lisp para uso digite load("stringproc");.

No Maxima uma sequência de caracteres é facilmente contruída digitando "texto" (qualquer texto desejado entre aspas duplas). Note que sequências de caracteres do Maxima não são sequências de caracteres do Lisp e vice-versa. Testes podem ser concluídos com stringp e lstringp. Se por alguma razão tiver um valor, que é uma sequência de caracteres do Lisp, talvez quando estiver usando a função sconcat do Maxima, poderá converter via sunlisp.

     (%i1) load("stringproc")$
     (%i2) m: "text";
     (%o2)                         text
     (%i3) [stringp(m),lstringp(m)];
     (%o3)                     [true, false]
     (%i4) l: sconcat("text");
     (%o4)                         text
     (%i5) [stringp(l),lstringp(l)];
     (%o5)                     [false, true]
     (%i6) stringp( sunlisp(l) );
     (%o6)                         true

Todas as funções em stringproc.lisp, que retornarem sequências de caracteres, retornam sequências de caracteres do Maxima.

Caracteres são introduzidos como sequências de caracteres do Maxima de comprimento 1. Com certeza, esses caracteres não são caracteres do Lisp. Testes podem ser realizados com charp ( lcharp e conversões do Lisp para o Maxima com cunlisp).

     (%i1) load("stringproc")$
     (%i2) c: "e";
     (%o2)                           e
     (%i3) [charp(c),lcharp(c)];
     (%o3)                     [true, false]
     (%i4) supcase(c);
     (%o4)                           E
     (%i5) charp(%);
     (%o5)                         true

Novamente, todas as funções em stringproc.lisp, que retornam caracteres, retornam caracteres do Maxima.  devido a esse facto, que os caracteres introduzidos são sequências de caracteres de comprimento 1, pode usar muitas das funções de sequência de caracteres também para caracteres. Como visto, supcase é um exemplo.

É importante saber, que o primeiro caractere em uma sequência de caracteres do Maxima éstá na posição 1. Isso é designado devido ao facto de o primeiro elemento em uma lista do Maxima está na posição 1 também. Veja definições de charat e de charlist para obter exemplos.

Em aplicações fnções de sequência de caractere são muitas vezes usadas quando estamos trabalhando com ficheiros.  Poderá encontrará algumas funções úteis de fluxo e de impressão em stringproc.lisp.  O seguinte exemplo mostra algumas das funções aqui introduzidas no trabalho.

Exemplo:

openw retorna um fluxo de saída para um ficheiro, printf então permite escrita formatada para esse ficheiro. Veja printf para detalhes.

     (%i1) load("stringproc")$
     (%i2) s: openw("E:/file.txt");
     (%o2)                    #<output stream E:/file.txt>
     (%i3) for n:0 thru 10 do printf( s, "~d ", fib(n) );
     (%o3)                                done
     (%i4) printf( s, "~%~d ~f ~a ~a ~f ~e ~a~%",
                   42,1.234,sqrt(2),%pi,1.0e-2,1.0e-2,1.0b-2 );
     (%o4)                                false
     (%i5) close(s);
     (%o5)                                true

Após fechar o fluxo pode abrí-lo novamente, dessa vez com direção de entrada.  readline retorna a linha completa como uma sequência de caracteres. O pacote stringproc agora oferece muitas funções para manipulação de sequências de caracteres. A troca de indicações/fichas pode ser realizada por split ou por tokens.

     (%i6) s: openr("E:/file.txt");
     (%o6)                     #<input stream E:/file.txt>
     (%i7) readline(s);
     (%o7)                     0 1 1 2 3 5 8 13 21 34 55
     (%i8) line: readline(s);
     (%o8)               42 1.234 sqrt(2) %pi 0.01 1.0E-2 1.0b-2
     (%i9) list: tokens(line);
     (%o9)           [42, 1.234, sqrt(2), %pi, 0.01, 1.0E-2, 1.0b-2]
     (%i10) map( parsetoken, list );
     (%o10)           [42, 1.234, false, false, 0.01, 0.01, false]

parsetoken somente analiza números inteiros e em ponto flutuante. A análise de símbolos ou grandes números em ponto flutuante precisa de parse_string, que pode ser disponibilizada para uso através de eval_string.lisp.

     (%i11) load("eval_string")$
     (%i12) map( parse_string, list );
     (%o12)           [42, 1.234, sqrt(2), %pi, 0.01, 0.01, 1.0b-2]
     (%i13) float(%);
     (%o13) [42.0, 1.234, 1.414213562373095, 3.141592653589793, 0.01, 0.01, 0.01]
     (%i14) readline(s);
     (%o14)                               false
     (%i15) close(s)$

readline retorna false quado o fim de ficheiro acontecer.

Definicedilhaões para entrada e saída
=====================================

Exemplo:

     (%i1) load("stringproc")$
     (%i2) s: openw("E:/file.txt");
     (%o2)                     #<output stream E:/file.txt>
     (%i3) control:
     "~2tAn atom: ~20t~a~%~2tand a list: ~20t~{~r ~}~%~2tand an integer: ~20t~d~%"$
     (%i4) printf( s,control, 'true,[1,2,3],42 )$
     (%o4)                                false
     (%i5) close(s);
     (%o5)                                true
     (%i6) s: openr("E:/file.txt");
     (%o6)                     #<input stream E:/file.txt>
     (%i7) while stringp( tmp:readline(s) ) do print(tmp)$
       An atom:          true
       and a list:       one two three
       and an integer:   42
     (%i8) close(s)$

 -- Função: close (FLUXO)
     Fecha  FLUXO e retorna true se FLUXO tiver sido aberto anteriormente.

 -- Função: flength (FLUXO)
     Retorna o número de elementos em FLUXO.

 -- Função: fposition (FLUXO)
 -- Função: fposition (FLUXO, POS)
     Retorna a posição corrente em FLUXO, se POS não está sendo usada. Se POS estiver sendo usada, fposition escolhe a posição em FLUXO. POS tem que ser um número positivo, o primeiro elemento em FLUXO está na posição 1.

 -- Função: freshline ()
 -- Função: freshline (FLUXO)
     escreve uma nova linha (em FLUXO), se a posição actual não for um início de linha. Veja também newline.

 -- Função: newline ()
 -- Função: newline (FLUXO)
     Escreve uma nova linha (para FLUXO). Veja sprint para um exemplo de uso de newline(). Note que existem alguns casos, onde newline()não trabalha como esperado.

 -- Função: opena (FICHEIRO)
     Retorna um fluxo de saída para FICHEIRO. Se um ficheiro já existente tiver sido aberto, opena anexa os elementos ao final do ficheiro.

 -- Função: openr (FICHEIRO)
     Retorna um fluxo para FICHEIRO. Se FICHEIRO não existir, ele será criado.

 -- Função: openw (FICHEIRO)
     Retorna um fluxo de saída para FICHEIRO. Se FICHEIRO não existir, será criado. Se um ficheiro já existente for aberto, openw modifica destrutivametne o FICHEIRO.

 -- Função: printf (DEST, SEQ_CARACTE)
 -- Função: printf (DEST, SEQ_CARACTE, EXPR_1, ..., EXPR_N)
     Torna a função FORMAT do Lisp Comum disponível no Maxima. (Retirado de gcl.info: "format produces formatted output by outputting the caracteres of control-string string and observing that a tilde introduces a directive. The caractere after the tilde, possibly preceded by prefix parameters and modifiers, specifies what kind of formatting is desired. Most directives use one or more elements of args to create their output.")

     A seguinte descrição e oa exemplos podem fornecer uma idéia de uso de printf. Veja um referência de Lisp para maiores informações.

             ~%       nova linha
             ~&       novíssima line
             ~t       tabulação
             ~$       monetário
             ~d       inteiro decimal
             ~b       inteiro binário
             ~o       inteiro octal
             ~x       inteiro hexadecimal
             ~br      inteiro de base b
             ~r       soletra um inteiro
             ~p       plural
             ~f       ponto flutuante
             ~e       notação científica
             ~g       ~f ou ~e, dependendo  da magnitude
             ~a       como mostrado pela função print do Maxima
             ~s       sequências de caracteres entre "aspas duplas"
             ~~       ~
             ~<       justificação de texto, ~> terminador de justificação de texto
             ~(       conversão de caixa alta/baixa, ~) terminador de conversão de caixa
             ~[       selecção, ~] terminador de selecção
             ~{       iteração, ~} terminador de iteração

     Por favor note que não existe especificador de formato para grandes números em ponto flutuante. Todavia grandes números em ponto flutuante podem simplesmente serem mostrados por meio da directiva ~a.  ~s mostra as sequências de caracteres entre "aspas duplas"; pode evitar isso usando ~a.  Note que a directiva de selecção ~[ é indexada em zero.  Também note que existem algumas directivas, que não trabalham no Maxima.  Por exemplo, ~:[ falha.

          (%i1) load("stringproc")$
          (%i2) printf( false, "~a ~a ~4f ~a ~@r",
                        "String",sym,bound,sqrt(12),144), bound = 1.234;
          (%o2)                 String sym 1.23 2*sqrt(3) CXLIV
          (%i3) printf( false,"~{~a ~}",["one",2,"THREE"] );
          (%o3)                          one 2 THREE
          (%i4) printf( true,"~{~{~9,1f ~}~%~}",mat ),
                        mat = args( matrix([1.1,2,3.33],[4,5,6],[7,8.88,9]) )$
                1.1       2.0       3.3
                4.0       5.0       6.0
                7.0       8.9       9.0
          (%i5) control: "~:(~r~) bird~p ~[is~;are~] singing."$
          (%i6) printf( false,control, n,n,if n=1 then 0 else 1 ), n=2;
          (%o6)                    Two birds are singing.

     Se DEST for um fluxo ou true, então printf retorna false. De outra forma, printf retorna uma sequência de caracteres contendo a saída.

 -- Função: readline (FLUXO)
     Retorna uma sequência de caracteres contendo os caracteres a partir da posição corrente em FLUXO até o fim de linha ou FALSE se o fim de linha do ficheiro for encontrado.

 -- Função: sprint (EXPR_1, ..., EXPR_N)
     Avalia e mostra seus argumentos um após o outro `sobre uma linha' iniciando na posição mais à esquerda.  Os números são mostrados com o '-' à direita do número, e isso desconsidera o comprimento da linha. newline(), que pode ser chamada a partir de stringproc.lisp pode ser útil, se desejar colocar uma parada de linha intermédia.

          (%i1) for n:0 thru 22 do sprint( fib(n) )$
          0 1 1 2 3 5 8 13 21 34 55 89 144 233 377 610 987 1597 2584 4181 6765 10946 17711
          (%i2) load("stringproc")$
          (%i3) for n:0 thru 22 do (
                   sprint(fib(n)), if mod(n,10)=9 then newline() )$
          0 1 1 2 3 5 8 13 21 34
          55 89 144 233 377 610 987 1597 2584 4181
          6765 10946 17711

Definicedilhaões para caracteres
================================

 -- Função: alphacharp (CARACTERE)
     Retorna true se CARACTERE for um caractere alfabético.

 -- Função: alphanumericp (CARACTERE)
     Retorna true se CARACTERE for um caractere alfabético ou um dígito.

 -- Função: ascii (INT)
     Retorna o caractere correspondente ao código numérico ASCII INT. ( -1 < int < 256 )

          (%i1) load("stringproc")$
          (%i2) for n from 0 thru 255 do (
          tmp: ascii(n), if alphacharp(tmp) then sprint(tmp), if n=96 then newline() )$
          A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
          a b c d e f g h i j k l m n o p q r s t u v w x y z

 -- Função: cequal (CARACTERE_1, CARACTERE_2)
     Retorna true se CARACTERE_1 e CARACTERE_2 forem os mesmos.

 -- Função: cequalignore (CARACTERE_1, CARACTERE_2)
     como cequal mas ignora a caixa alta/baixa.

 -- Função: cgreaterp (CARACTERE_1, CARACTERE_2)
     Retorna true se o código numérico ASCII do CARACTERE_1 for maior que o código numérico ASCII do CARACTERE_2.

 -- Função: cgreaterpignore (CARACTERE_1, CARACTERE_2)
     Como cgreaterp mas ignora a caixa alta/baixa.

 -- Função: charp (OBJ)
     Retorna true se OBJ for um caractere do Maxima. Veja na seção "Introducedilhaão a manipulacedilhaão de sequências de caracteres" para ter um exemplo.

 -- Função: cint (CARACTERE)
     Retorna o código numéico ASCII de CARACTERE.

 -- Função: clessp (CARACTERE_1, CARACTERE_2)
     Retorna true se o código numérico ASCII de CARACTERE_1 for menor que o código numérico ASCII de CARACTERE_2.

 -- Função: clesspignore (CARACTERE_1, CARACTERE_2)
     Como em clessp ignora a caixa alta/baixa.

 -- Função: constituent (CARACTERE)
     Retorna true se CARACTERE for caractere  gráfico e não o caractere de espaço em branco. Um caractere gráfico é um caractere que se pode ver, adicionado o caractere de espaço em branco. (constituent foi definida por Paul Graham, em ANSI Common Lisp, 1996, página 67.)

          (%i1) load("stringproc")$
          (%i2) for n from 0 thru 255 do (
          tmp: ascii(n), if constituent(tmp) then sprint(tmp) )$
          ! " #  %  ' ( ) * + , - . / 0 1 2 3 4 5 6 7 8 9 : ; < = > ? @ A B
          C D E F G H I J K L M N O P Q R S T U V W X Y Z [ \ ] ^ _ ` a b c
          d e f g h i j k l m n o p q r s t u v w x y z { | } ~

 -- Função: cunlisp (LISP_CHAR)
     Converte um caractere do Lisp em um caractere do Maxima.  (É possível que não chegue a precisar dessa função.)

 -- Função: digitcharp (CARACTERE)
     Retorna true se CARACTERE for um dígito (algarismo de 0 a 9).

 -- Função: lcharp (OBJ)
     Retorna true se OBJ for um caractere do Lisp. (Pode não precisar dessa função.)

 -- Função: lowercasep (CARACTERE)
     Retorna true se CARACTERE for um caractere em caixa baixa.

 -- Variable: newline
     O caractere de nova linha.

 -- Variável: space
     O caractere de espaço em branco.

 -- Variável: tab
     O caractere de tabulação.

 -- Função: uppercasep (CARACTERE)
     Retorna true se CARACTERE for um caractere em caixa alta.

Definicedilhaões para sequências de caracteres
==============================================

 -- Função: sunlisp (LISP_STRING)
     Converte uma sequência de caracteres do Lisp em uma sequência de caracteres do Maxima. (Em geral, pode não chegar a precisar dessa função.)

 -- Função: lstringp (OBJ)
     Retorna true se OBJ is uma sequência de caracteres do Lisp. (Em geral, pode não chegar a precisar dessa função.)

 -- Função: stringp (OBJ)
     Retorna true se OBJ for uma sequência de caracteres do Maxima. Veja a introdução para obter exemplos.

 -- Função: charat (SEQ_CARACTE, N)
     Retorna o N-ésimo caractere de SEQ_CARACTE. O primeiro caractere em SEQ_CARACTE é retornado com N = 1.

          (%i1) load("stringproc")$
          (%i2) charat("Lisp",1);
          (%o2)                           L

 -- Função: charlist (SEQ_CARACTE)
     Retorna a lsita de todos os caracteres em SEQ_CARACTE.

          (%i1) load("stringproc")$
          (%i2) charlist("Lisp");
          (%o2)                     [L, i, s, p]
          (%i3) %[1];
          (%o3)                           L

 -- Função: parsetoken (SEQ_CARACTE)
     parsetoken converte a primeira ficha em SEQ_CARACTE para o correspondente número ou retorna false se o número não puder ser determinado. O conjunto de delimitadores para a troca de fichas é {space, comma, semicolon, tab, newline}

     Nota de tradução: espaço, vírgula, ponto e vírgula, tabulação e nova linha.

          (%i1) load("stringproc")$
          (%i2) 2*parsetoken("1.234 5.678");
          (%o2)                         2.468

     Para analizar, pode também usar a função parse_string. Veja a descrição no ficheiro 'share\contrib\eval_string.lisp'.

 -- Função: sconc (EXPR_1, ..., EXPR_N)
     Avalia seus argumentos e concatena-os em uma sequência de caracteres. sconc é como sconcat mas retorna uma sequência de caracteres do Maxima.

          (%i1) load("stringproc")$
          (%i2) sconc("xx[",3,"]:",expand((x+y)^3));
          (%o2)             xx[3]:y^3+3*x*y^2+3*x^2*y+x^3
          (%i3) stringp(%);
          (%o3)                         true

 -- Função: scopy (SEQ_CARACTE)
     Retorna uma cópia de SEQ_CARACTE como uma nova sequência de caracteres.

 -- Função: sdowncase (SEQ_CARACTE)
 -- Função: sdowncase (SEQ_CARACTE, INÍCIO)
 -- Função: sdowncase (SEQ_CARACTE, INÍCIO, FIM)
     Como em supcase, mas caracteres em caixa alta são convertidos para caracteres em caixa baixa.

 -- Função: sequal (SEQ_CARACTE__1, SEQ_CARACTE__2)
     Retorna true se SEQ_CARACTE__1 e SEQ_CARACTE__2 tiverem o mesmo comprimento e contiverem os mesmos caracteres.

 -- Função: sequalignore (SEQ_CARACTE__1, SEQ_CARACTE__2)
     Como em sequal mas igonara a caixa alta/baixa.

 -- Função: sexplode (SEQ_CARACTE)
     sexplode é um apelido para a função charlist.

 -- Função: simplode (LISTA)
 -- Função: simplode (LISTA, DELIM)
     simplode takes uma lista ou expressões  e concatena-as em uma sequência de caracteres. Se nenhum delimitador DELIM for usado, simplode funciona como sconc e não utiliza delimitador. DELIM pode ser qualquer sequência de caracteres.

          (%i1) load("stringproc")$
          (%i2) simplode(["xx[",3,"]:",expand((x+y)^3)]);
          (%o2)             xx[3]:y^3+3*x*y^2+3*x^2*y+x^3
          (%i3) simplode( sexplode("stars")," * " );
          (%o3)                   s * t * a * r * s
          (%i4) simplode( ["One","more","coffee."]," " );
          (%o4)                   One more coffee.

 -- Função: sinsert (SEQ, SEQ_CARACTE, POS)
     Retorna uma sequência de caracteres que é uma concatenação de substring (SEQ_CARACTE, 1, POS - 1), a sequência de caracteres SEQ e substring (SEQ_CARACTE, POS). Note que o primeiro caractere está em SEQ_CARACTE e está na posição 1.

          (%i1) load("stringproc")$
          (%i2) s: "A submarine."$
          (%i3) sconc( substring(s,1,3),"yellow ",substring(s,3) );
          (%o3)                  A yellow submarine.
          (%i4) sinsert("hollow ",s,3);
          (%o4)                  A hollow submarine.

 -- Função: sinvertcase (SEQ_CARACTE)
 -- Função: sinvertcase (SEQ_CARACTE, INÍCIO)
 -- Função: sinvertcase (SEQ_CARACTE, INÍCIO, FIM)
     Retorna SEQ_CARACTE excepto que cada caractere da posição INÍCIO até a posição FIM está invertido. Se a posição FIM não for fornecida, todos os caracteres do início ao FIM de SEQ_CARACTE são substituídos.

          (%i1) load("stringproc")$
          (%i2) sinvertcase("sInvertCase");
          (%o2)                      SiNVERTcASE

 -- Função: slength (SEQ_CARACTE)
     Retorna número de caracteres em SEQ_CARACTE.

 -- Função: smake (NUM, CARACTERE)
     Retorna uma nova sequência de caracteres repetindo NUM vezes CARACTERE.

          (%i1) load("stringproc")$
          (%i2) smake(3,"w");
          (%o2)                          www

 -- Função: smismatch (SEQ_CARACTE__1, SEQ_CARACTE__2)
 -- Função: smismatch (SEQ_CARACTE__1, SEQ_CARACTE__2, TEST)
     Retorna a posição do primeiro caractere de SEQ_CARACTE__1 no qual SEQ_CARACTE__1 e SEQ_CARACTE__2 diferem ou false em caso contrário. A função padrao de teste para coincidência é sequal. Se smismatch pode ignorar a caixa alta/baixa, use sequalignore como função de teste.

          (%i1) load("stringproc")$
          (%i2) smismatch("seven","seventh");
          (%o2)                           6

 -- Função: split (SEQ_CARACTE)
 -- Função: split (SEQ_CARACTE, DELIM)
 -- Função: split (SEQ_CARACTE, DELIM, MULTIPLE)
     Retorna a lista de todas as fichas em SEQ_CARACTE. Cada ficha é uma sequência de caracteres não analisada. split usa DELIM como delimitador. Se DELIM não for fornecido, o caractere de espaço é o delimitador padrão. MULTIPLE é uma variável booleana com true como valor padrão. Multiplos delimitadores são lidos como um. Essa função é útil se tabulações são gravadas com caracteres de espaço multiplos. Se MULTIPLE for escolhido para false, cada delimitador é considerado.

          (%i1) load("stringproc")$
          (%i2) split("1.2   2.3   3.4   4.5");
          (%o2)                 [1.2, 2.3, 3.4, 4.5]
          (%i3) split("first;;third;fourth",";",false);
          (%o3)               [first, , third, fourth]

 -- Função: sposition (CARACTERE, SEQ_CARACTE)
     Retorna a posição do primeiro caractere em SEQ_CARACTE que coincide com CARACTERE. O primeiro caractere em SEQ_CARACTE está na posição 1. Para que os caracteres que coincidirem desconsiderem a caixa alta/baixa veja ssearch.

 -- Função: sremove (SEQ, SEQ_CARACTE)
 -- Função: sremove (SEQ, SEQ_CARACTE, TEST)
 -- Função: sremove (SEQ, SEQ_CARACTE, TEST, INÍCIO)
 -- Função: sremove (SEQ, SEQ_CARACTE, TEST, INÍCIO, FIM)
     Retorna uma sequência de caracteres como SEQ_CARACTE mas com todas as subsequências de caracteres que coincidirem com SEQ. A função padrão de teste de coincidência é sequal. Se sremove puder ignorar a caixa alta/baixa enquanto busca por SEQ, use sequalignore como teste. Use INÍCIO e FIM para limitar a busca. Note que o primeiro caractere em SEQ_CARACTE está na posição 1.

          (%i1) load("stringproc")$
          (%i2) sremove("n't","I don't like coffee.");
          (%o2)                   I do like coffee.
          (%i3) sremove ("DO ",%,'sequalignore);
          (%o3)                    I like coffee.

 -- Função: sremovefirst (SEQ, SEQ_CARACTE)
 -- Função: sremovefirst (SEQ, SEQ_CARACTE, TEST)
 -- Função: sremovefirst (SEQ, SEQ_CARACTE, TEST, INÍCIO)
 -- Função: sremovefirst (SEQ, SEQ_CARACTE, TEST, INÍCIO, FIM)
     Como em sremove excepto que a primeira subsequência de caracteres que coincide com seq é removida.

 -- Função: sreverse (SEQ_CARACTE)
     Retorna uma sequência de caracteres com todos os caracteres de SEQ_CARACTE em ordem reversa.

 -- Função: ssearch (SEQ, SEQ_CARACTE)
 -- Função: ssearch (SEQ, SEQ_CARACTE, TEST)
 -- Função: ssearch (SEQ, SEQ_CARACTE, TEST, INÍCIO)
 -- Função: ssearch (SEQ, SEQ_CARACTE, TEST, INÍCIO, FIM)
     Retorna a posição da primeira subsequência de caracteres de SEQ_CARACTE que coincide com a sequência de caracteres SEQ. A função padrão de teste de coincidência é sequal. Se ssearch puder igonorar a caixa alta/baixa, use sequalignore como função de teste. Use INÍCIO e FIM para limitar a busca. Note que o primeiro caracter em SEQ_CARACTE está na posição 1.

          (%i1) ssearch("~s","~{~S ~}~%",'sequalignore);
          (%o1)                                  4

 -- Função: ssort (SEQ_CARACTE)
 -- Função: ssort (SEQ_CARACTE, TEST)
     Retorna uma sequência de caracteres que contém todos os caracteres de SEQ_CARACTE em uma ordem tal que não existam dois caracteres C sucessivos e D seja tal que test (C, D) seja false e test (D, C) seja true. A função padrão de teste para ordenação é CLESSP. O conjunto de funções de teste é {clessp, clesspignore, cgreaterp, cgreaterpignore, cequal, cequalignore}.

          (%i1) load("stringproc")$
          (%i2) ssort("I don't like Mondays.");
          (%o2)                    '.IMaddeiklnnoosty
          (%i3) ssort("I don't like Mondays.",'cgreaterpignore);
          (%o3)                 ytsoonnMlkIiedda.'

 -- Função: ssubst (NOVA, ANTIGA, SEQ_CARACTE)
 -- Função: ssubst (NOVA, ANTIGA, SEQ_CARACTE, TEST)
 -- Função: ssubst (NOVA, ANTIGA, SEQ_CARACTE, TEST, INÍCIO)
 -- Função: ssubst (NOVA, ANTIGA, SEQ_CARACTE, TEST, INÍCIO, FIM)
     Retorna uma sequência de caracteres como SEQ_CARACTE excepto que todas as subsequências de caracteres que coincidirem com ANTIGA são substituídas por NOVA. ANTIGA e NOVA não precisam ser de mesmo comprimento. A função padrão de teste para coincidência é para coincidências é sequal. Se ssubst puder ignorar a cixa alta/baixa enquanto procurando por ANTIGA, use sequalignore como função de teste. Use INÍCIO e FIM para limitar a busca. Note que o primeiro caractere em SEQ_CARACTE está na posição 1.

          (%i1) load("stringproc")$
          (%i2) ssubst("like","hate","I hate Thai food. I hate green tea.");
          (%o2)          I like Thai food. I like green tea.
          (%i3) ssubst("Indian","thai",%,'sequalignore,8,12);
          (%o3)         I like Indian food. I like green tea.

 -- Função: ssubstfirst (NOVA, ANTIGA, SEQ_CARACTE)
 -- Função: ssubstfirst (NOVA, ANTIGA, SEQ_CARACTE, TEST)
 -- Função: ssubstfirst (NOVA, ANTIGA, SEQ_CARACTE, TEST, INÍCIO)
 -- Função: ssubstfirst (NOVA, ANTIGA, SEQ_CARACTE, TEST, INÍCIO, FIM)
     Como em subst excepto que somente a primeira subsequência de caracteres que coincidir com ANTIGA é substituída.

 -- Função: strim (SEQ,SEQ_CARACTE)
     Retorna uma sequência de caracteres como SEQ_CARACTE, mas com todos os caracteres que aparecerem em SEQ removidos de ambas as extremidades.

          (%i1) load("stringproc")$
          (%i2) "/* comment */"$
          (%i3) strim(" /*",%);
          (%o3)                        comment
          (%i4) slength(%);
          (%o4)                           7

 -- Função: striml (SEQ, SEQ_CARACTE)
     Como em strim excepto que somente a extremidade esquerda de SEQ_CARACTE é recordada.

 -- Função: strimr (SEQ, SEQ_CARACTE)
     Como em strim excepto que somente a extremidade direita de sequência de caracteres é recortada.

 -- Função: substring (SEQ_CARACTE, INÍCIO)
 -- Função: substring (SEQ_CARACTE, INÍCIO, FIM)
     Retorna a subsequência de caracteres de SEQ_CARACTE começando na posição INÍCIO e terminando na posição FIM. O caractere na posição FIM não é incluído. Se FIM não for fornecido, a subsequência de caracteres contém o restante da sequência de caracteres. Note que o primeiro caractere em SEQ_CARACTE está na posição 1.

          (%i1) load("stringproc")$
          (%i2) substring("substring",4);
          (%o2)                        string
          (%i3) substring(%,4,6);
          (%o3)                          in

 -- Função: supcase (SEQ_CARACTE)
 -- Função: supcase (SEQ_CARACTE, INÍCIO)
 -- Função: supcase (SEQ_CARACTE, INÍCIO, FIM)
     Retorna SEQ_CARACTE excepto que caracteres em caixa baixa a partir da posição INÍCIO até a posição FIM são substituídos pelo correspondente caracteres em cixa alta. Se FIM não for fornecido, todos os caracteres em caixa baixa de INÍCIO até o fim de SEQ_CARACTE são substituídos.

          (%i1) load("stringproc")$
          (%i2) supcase("english",1,2);
          (%o2)                        English

 -- Função: tokens (SEQ_CARACTE)
 -- Função: tokens (SEQ_CARACTE, TEST)
     Retorna uma lista de fichas, que tiverem sido extrídos de SEQ_CARACTE. As fichas são subsequências de caracteres cujos caracteres satisfazem a uma determinada função de teste. Se o teste não for fornecido, CONSTITUENT é usada como teste padrão. {constituent, alphacharp, digitcharp, lowercasep, uppercasep, charp, characterp, alphanumericp} é o conjunto de fnç~oes de teste. (A versão Lisp de tokens é escrita por Paul Graham. ANSI Common Lisp, 1996, page 67.)

          (%i1) load("stringproc")$
          (%i2) tokens("24 October 2005");
          (%o2)                  [24, October, 2005]
          (%i3) tokens("05-10-24",'digitcharp);
          (%o3)                     [05, 10, 24]
          (%i4) map(parsetoken,%);
          (%o4)                      [5, 10, 24]